Double Integrals in Polar Coordinates. 

Example I : Find limits of integration for the double integral of f(x,y) over R, if R is the area inside the cardioid r = 1+cos θ and outside the circle r=1.

PolarPlot[{1+Cos[theta], 1},{theta,0,2Pi},AxesLabel-> {x,y} ]

(* Showing the region using RegionPlot *)
Show[
PolarPlot[{1+Cos[theta], 1},{theta,0,2Pi},AxesLabel-> {x,y} ],
RegionPlot[1<r< 1+Cos[theta],{r,1,2},{theta,-Pi/2,Pi/2},PlotPoints->30]/.
GraphicsComplex[a_,b__]:>GraphicsComplex[#1 {Cos[#2],Sin[#2]}&@@@a,b]
]

(* Integrate f over region R in polar coordinates *)
f[x_,y_]:=4+x^2+y^2; (* then f(x,y) = 4+r^2 *)

Integrate[(4+r^2)*r ,{theta,-Pi/2,Pi/2},{r,1,1+Cos[theta]}] (* dA = rdrdθ *)

(* Area of region R above *)
Integrate[r ,{theta,-Pi/2,Pi/2},{r,1,1+Cos[theta]}] (* dA = rdrdθ *)

Example II :  Find the area enclosed by one petal of the rose r = cos 3θ using double integral.

PolarPlot[Cos[3*theta] ,{theta,0, 2Pi},AxesLabel->{x,y}]

(* Using symmetry *)
2*Integrate[r,{theta,0,Pi/6},{r,0,Cos[3*theta]}](* dA = rdrdθ *)

Example III :  Changing Cartesian integrals to polar integrals. 
Find the volume under the paraboloid z=(x^2)+(y^2), above the xy-plane and inside the cylinder (x^2)+(y^2)=2x.

ContourPlot3D[{z==x^2+y^2, x^2+y^2==2x},{x,-2,2},{y,-2,2},{z,0,10}, Mesh->None,
AxesLabel->{x,y,z}, ContourStyle -> Opacity[0.6]]

RegionPlot3D[0≤z<=x^2+y^2&& 0<=x^2+y^2<=2x,{x,0,2},{y,-2,2},{z,0,10},PlotPoints ->150,PlotRange -> All,PlotStyle->Directive[Yellow,Opacity[0.6]], AxesLabel->{x,y,z},
Mesh -> None]

(* Region using RegionPlot *)
Show[
PolarPlot[{0,2*Cos[theta]},{theta,0,2Pi},AxesLabel-> {x,y} ],
RegionPlot[0<r<2*Cos[theta],{r,0,2},{theta,-Pi/2,Pi/2},PlotPoints->30]/.
GraphicsComplex[a_,b__]:>GraphicsComplex[#1 {Cos[#2],Sin[#2]}&@@@a,b]
]

(* Finding volume using double integral in polar form *)
Integrate[(r^2)*r,{theta,-Pi/2,Pi/2},{r,0,2Cos[theta]}]