MTH 212 Lab on 02/10/2020. Curves, Arc Length, Reparameterization, TNB-Frame (Sections 12.3, 12.4)

Consider examples:

(* circle *)
r1[t_]:={ Cos[t],Sin[t]}
ParametricPlot[r1[t], {t,-2Pi,2Pi},AxesLabel->{x,y}]

(* helix *)
r2[t_]:={ Cos[t],Sin[t],t}
ParametricPlot3D[r2[t], {t,-2Pi,2Pi},AxesLabel->{x,y,z}]

Displaying a tangent line to the helix curve at t=2π/3 for the helix

TangentLine[t_]:=r2[2Pi/3]+t * r2'[2Pi/3] (*vector equation of the tangent line*)
Show[
(* tangent line *) ParametricPlot3D[{r2[t],TangentLine[t]}, {t,-2Pi,2Pi},AxesLabel->{x,y,z}],
(* tangent vector *) Graphics3D[{Arrowheads[.03],Arrow[{r2[2Pi/3],r2[2Pi/3]+r2'[2Pi/3]}]}],
(* point *) Graphics3D[{PointSize[.02],Point[{r2[2Pi/3]}]}]
]

Arc Length

(* of the circle *)
Integrate[Sqrt[r1'[t].r1'[t]],{t,0,2Pi}]

(* of the helix, t=0 to 2π *)
Integrate[Sqrt[r2'[t].r2'[t]],{t,0,2Pi}]

Reparameterization of the helix

rr2[s_]:={Cos[s/Sqrt[2]],Sin[s/Sqrt[2]],s/Sqrt[2]} (* same helix as above! *)
ParametricPlot3D[rr2[s], {s,-3Pi,3Pi},AxesLabel->{x,y,z}]

(* Unit tangent vector turns as the curve bends *)
Manipulate[
Show[
ParametricPlot3D[r2[t],{t,0,4Pi},PlotRange-> {{-2,2},{-2,2},{ 0, 4Pi}}],
Graphics3D[{Arrowheads[.025],Arrow[{r2[ts],r2[ts]+rT[ts]}],Text[Style["T",Bold],{r2[ts]+rT[ts]}]}],
Graphics3D[{PointSize[.02],Point[{r2[ts]}]}]
],
{ts,0,4Pi}
]

Using a slider to show the TNB-frame for a space curve:

(* our curve is a helix *)
rT[t_]:=r2'[t]/Sqrt[r2'[t].r2'[t]] (* T, the unit tangent to the curve *)
rN[t_]:=rT'[t]/Sqrt[rT'[t].rT'[t]](* N, the principal unit normal vector *)
rB[t_]:= Cross[rT[t],rN[t]] (* B, the binormal unit vector *) 

Manipulate[
Show[
ParametricPlot3D[r2[t],{t,0,4Pi},PlotRange-> {{-2,2},{-2,2},{ 0, 4Pi}}],
Graphics3D[{Arrowheads[.025],
		Arrow[{r2[ts],r2[ts]+rT[ts]}],Text[Style["T",Bold],{r2[ts]+rT[ts]}],
		Red, Arrow[{r2[ts],r2[ts]+rN[ts]}],Text[Style["N",Bold],{r2[ts]+rN[ts]}],
		Blue, Arrow[{r2[ts],r2[ts]+rB[ts]}],Text[Style["B",Bold],{r2[ts]+rB[ts]}]
}]
],
{ts,0,4Pi}
]